How do I overwrite a bad/unconfigured K1000 Agent install?
I found that we have an issue where the K1000 agent was installed during imaging prior to machines being joined to the domain. They cant check in and thus don't show up in inventory. If i manually uninstall the agent, and then allow our GPO to push the agent install again the issue is resolved. I would like to not have to manually uninstall all the agents that are out there and not working if possible. Is there a way to repair the install of the agent to get it to work via GP or K1000? Is there a way to have the GPO automatically overwrite the per-existing install? Has anyone had this issue or maybe had to move a set of machines from one K1 to another?
0 Comments
[ + ] Show comments
Answers (2)
Answer Summary:
Please log in to answer
Posted by:
pg_fr_69
6 years ago
Top Answer
@j.catlin :
we have encountered a similar problem as yours. To correct this, we create a specific GPO that contains a startup script applied to all AD computers to verify if the amp.conf is correctly set and repair it if needed.
here the script :
-------------------
@echo off
setlocal EnableDelayedExpansion
set ProductName=QUEST KACE Agent
set k1000server=<<your k1000 fqdn>>
if %PROCESSOR_ARCHITECTURE%==x86 (set arch=x86) else (set arch=x64)
if %arch%==x86 (set pgmFiles=%ProgramFiles%) else set pgmFiles=%ProgramFiles(x86)%
::disable UNC exec warnings
(reg add "HKCU\software\microsoft\Command Processor" /v DisableUNCCheck /t REG_DWORD /d 1 /f) >nul 2>&1
::check main exe
echo Check %ProductName% main exe :
if exist "!pgmFiles!\dell\kace\konea.exe" (
echo OK
echo+
goto check_agent_config
)
echo %ProductName% NOT found. Exiting.
echo+
goto end
::agent installed, K1000 link might be missing...
:check_agent_config
echo Check %ProductName% config file :
type "%ALLUSERSPROFILE%\dell\kace\amp.conf" | findstr /i %k1000server% >nul
if %errorlevel%==0 (
echo Check OK. Exiting.
echo+
goto end
)
echo config is missing or badly configured : generate correct K1000 link...
echo+
::by setting the host variable with AmpTools EXE, konea service is reloaded automatically
:define_agent_config
echo Create %ProductName% config file :
cmd /c "!pgmFiles!\dell\kace\AmpTools.exe" set host=%k1000server%
echo Done. Exiting.
:: restart another check to verify if the config file is correctly set
goto check_agent_config
:end
endlocal
-------------------
we have encountered a similar problem as yours. To correct this, we create a specific GPO that contains a startup script applied to all AD computers to verify if the amp.conf is correctly set and repair it if needed.
here the script :
-------------------
@echo off
setlocal EnableDelayedExpansion
set ProductName=QUEST KACE Agent
set k1000server=<<your k1000 fqdn>>
if %PROCESSOR_ARCHITECTURE%==x86 (set arch=x86) else (set arch=x64)
if %arch%==x86 (set pgmFiles=%ProgramFiles%) else set pgmFiles=%ProgramFiles(x86)%
::disable UNC exec warnings
(reg add "HKCU\software\microsoft\Command Processor" /v DisableUNCCheck /t REG_DWORD /d 1 /f) >nul 2>&1
::check main exe
echo Check %ProductName% main exe :
if exist "!pgmFiles!\dell\kace\konea.exe" (
echo OK
echo+
goto check_agent_config
)
echo %ProductName% NOT found. Exiting.
echo+
goto end
::agent installed, K1000 link might be missing...
:check_agent_config
echo Check %ProductName% config file :
type "%ALLUSERSPROFILE%\dell\kace\amp.conf" | findstr /i %k1000server% >nul
if %errorlevel%==0 (
echo Check OK. Exiting.
echo+
goto end
)
echo config is missing or badly configured : generate correct K1000 link...
echo+
::by setting the host variable with AmpTools EXE, konea service is reloaded automatically
:define_agent_config
echo Create %ProductName% config file :
cmd /c "!pgmFiles!\dell\kace\AmpTools.exe" set host=%k1000server%
echo Done. Exiting.
:: restart another check to verify if the config file is correctly set
goto check_agent_config
:end
endlocal
-------------------
Posted by:
Nico_K
6 years ago
well, really depending why it does not check in.
Please check at first if the c:\programdata\dell\kace\amp.conf file is in place and good
(it needs one line at min: host = XXX where XXX is your appliance webserver name, IP or similar)
If this is not the case, change this by running
c:\program files (x86)\dell\kace\amptools.exe -resetconf host=XXX
You can also check in c:\programdata\dell\kace\user for the log files and errors. Depending on these errors multiple ways would be possible (also to solve the issue permanently)
If you need help to analyze the logs, post them here or open a ticket with KACE support.
Please check at first if the c:\programdata\dell\kace\amp.conf file is in place and good
(it needs one line at min: host = XXX where XXX is your appliance webserver name, IP or similar)
If this is not the case, change this by running
c:\program files (x86)\dell\kace\amptools.exe -resetconf host=XXX
You can also check in c:\programdata\dell\kace\user for the log files and errors. Depending on these errors multiple ways would be possible (also to solve the issue permanently)
If you need help to analyze the logs, post them here or open a ticket with KACE support.