/build/static/layout/Breadcrumb_cap_w.png

Epson Easy MP Installshield exe file problem

Hi Guys

Package file :EasyMP Multi PC Projection Utility v1.05
Unzip it and go to to Instdata to find the setup.exe file.

I ran setup.exe /r to record my iss file. It looks like very simple one :
[InstallShield Silent]
Version=v7.00
File=Response File
[File Transfer]
OverwrittenReadOnly=NoToAll
[Application]
Name=EasyMP Multi PC Projection Ver.1.05
Version=1.0.5.0
Company=SEIKO EPSON CORPORATION
Lang=040c
[{2018E638-9C1E-4627-9B6D-5E90CC648259}-DlgOrder]
Dlg0={2018E638-9C1E-4627-9B6D-5E90CC648259}-SdWelcome-0
Count=4
Dlg1={2018E638-9C1E-4627-9B6D-5E90CC648259}-SdLicense-0
Dlg2={2018E638-9C1E-4627-9B6D-5E90CC648259}-SdAskDestPath-0
Dlg3={2018E638-9C1E-4627-9B6D-5E90CC648259}-SdFinish-0
[{2018E638-9C1E-4627-9B6D-5E90CC648259}-SdWelcome-0]
Result=1
[{2018E638-9C1E-4627-9B6D-5E90CC648259}-SdLicense-0]
Result=1
[{2018E638-9C1E-4627-9B6D-5E90CC648259}-SdAskDestPath-0]
szDir=C:\Program Files (x86)\EPSON Projector\EasyMP Multi PC Projection V1
Result=1
[{2018E638-9C1E-4627-9B6D-5E90CC648259}-SdFinish-0]
Result=1
bOpt1=0
bOpt2=0


When running setup /s with this iss file as parameters the setup process keeps asking me for the license agreement whenever it is set to yes in the Iss.

It would be glad if someone can point me where the trouble could be.

Thanks a lot for any help


1 Comment   [ + ] Show comment
  • Hello
    It seems that it is not getting license agreement file so copy file License.FR (As your doing french version )from license folder present with source to same folder where setup.exe is present and then delete the license folder. then execute the iss file as follows
    e.g .
    setup.exe -s -f1c:\install.iss

    i tried many ways and finally the above solution worked for me.. - nonearme 10 years ago

Answers (11)

Posted by: dunnpy 12 years ago
Red Belt
0
How are you running setup.exe with the answer file?
Can you post your commandline?

If you recreate your answer file does it look exactly the same?
Posted by: orlith 12 years ago
Orange Senior Belt
0
Sure, here is the command line i wrote :

setup.exe /s /f1"c:\divers\test.iss"
I tried also
setup.exe -s -f1"c:\divers\test.iss"
setup.exe -s -f1c:\divers\test.iss
....

When recreating the answer file nothing change, the generated files are identical.

What I can add to my topic is that the lcense dialog box is the second one. The welcome dialog is not shown uring the silent install.
It is strange that only one dialog box doesn't work..


thanks for your reply
Posted by: jmaclaurin 12 years ago
Third Degree Blue Belt
0
Does it extract an MSI before install? You may have better luck working with that.
Posted by: orlith 12 years ago
Orange Senior Belt
0
Unfortunately no

thx
Posted by: aidbish 12 years ago
Yellow Belt
0
just wondering if you managed to resolve this as we have the same problem with the licesnse dialog still appearing
Posted by: orlith 12 years ago
Orange Senior Belt
0
Hi Aidbish

Yes I found a way by repackaging the installation using wininstallLE. I can share my msi package if it can help (I was not able to test it on other language laptops than French ones)
Posted by: orlith 12 years ago
Orange Senior Belt
0
By the way, I'm also in contact with Epson and told them to ask to the developpement team to do something on that. Don't know if I will be heard but why not ^^

Edit : I just had a phone conference with Epson and the answer is : "you're gonna have a msi version in around 10 days".

Great news
Posted by: greenerrabbit 12 years ago
Orange Belt
0
Hello,

Epson has released an msi version of the EasyMP client. It's not version 2.76. However, the only place you can download it is from the Epson UK site.

Here is a Google shortened link: http://goo.gl/hv69E

Once downloaded you can use your normal MSI commands to install: msiexec /i [file.msi] /qr is my command

Thanks, Ted
Posted by: orlith 12 years ago
Orange Senior Belt
0
Hi

Thanks for the link but , like you mention, this is EasyMp Client and not Multi PC Projection Utility v1.05 which are 2 differents program.
But thanks anyway for your search and links

FYI Epson France has released a french MSI for Multi PC Projection Utility v1.05 . For the moment there is no official download links. I'm testing this package.
Posted by: orlith 10 years ago
Orange Senior Belt
0
Option Explicit

Dim oShell, oFso, oFile, StrCurPath, path, startPath, transforms, endPath, ReturnVal, oEnv,sProgramFiles,sLogfile,sMSIInstallLog, sLogFolder, OSystem, sBits, sPlatform
Dim strComputer, objWMIService, wbemFlagReturnImmediately, wbemFlagForwardOnly, colItems, objItem, sVersion, oReg, sGuid, sProductCode, sStatus, sPackageName, sMsiFile, sMsiGUID
Dim sComputername, sType,oMSI, oNetwork, sMSIUninstallLog, View, Record,sAllUsersPrograms , sAllUsersDesktop, sSystemDrive, fo, sSystem, sSystemRoot, sProgramFilesx86, sMyCompany

Set oShell = CreateObject("WScript.Shell")
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oMSI=CreateObject("WindowsInstaller.Installer")

'------------------------------------------------------------------
sPackageName = "Epson MP MultiPC Projector 1.05 fr_FR"
sMsiFile = "EPSON EasyMP Multi PC Projection.msi"
sVersion = "1.05"
'------------------------------------------------------------------

path = WScript.ScriptFullName
StrCurPath = Left(path, InstrRev(path, "\"))
startPath = "Msiexec /i " & chr(34) & StrCurPath
transforms = chr(34) & " Transforms=" & chr(34) & StrCurPath
endPath = " /passive REBOOT=REALLYSUPPRESS ALLUSERS=2"
sPlatform = oShell.ExpandEnvironmentStrings( "%PROCESSOR_ARCHITECTURE%" ) 
sProgramFiles = oShell.ExpandEnvironmentStrings("%ProgramFiles%")
sProgramFilesx86 = oShell.ExpandEnvironmentStrings("%ProgramFiles(x86)%")
sAllUsersPrograms = oShell.SpecialFolders("AllUsersPrograms")
sAllUsersDesktop = oShell.SpecialFolders("AllUsersDesktop")
If sPlatform = "AMD64" Then
	sMyCompany = sProgramFilesx86 & "\MyCompany"
Else
	sMyCompany = sProgramFiles & "\MyCompany"
End If
sLogFolder = sMyCompany + "\logs\"
sLogfile = sLogFolder & sPackageName &".log"
sMSIInstallLog = sLogFolder & "Appl_Install_" & sPackageName & ".Log"
sMSIUninstallLog = sLogFolder & "Appl_Uninstall_" & sPackageName & ".Log"
Set oFile=oFso.OpenTextFile(sLogfile,2,True)
oFile.close

'-------- BEGIN ------------

Set oEnv = oShell.Environment("PROCESS")
oEnv("SEE_MASK_NOZONECHECKS") = 1

Log("Installation "& sPackageName)
preinstall()
Install()			
Registry()
Set oShell = Nothing
oEnv.Remove("SEE_MASK_NOZONECHECKS")

'-------- END ------------

Function Log(sEntry)
    Set oFile=oFso.OpenTextFile(sLogfile,8,True)
    'WScript.echo Now & " : " & sEntry
    oFile.writeline Now & " : " & sEntry
    oFile.close
End Function

Function Fail (Message)
   Log Message & "Installation failed!"
   oShell.Popup Message, 20, "Installation failed!", 16
   WScript.Quit 1
End Function

Function PreInstall()
	'remove older selfmade version
	MSI_GetPackageStatusByGuid("{65B612C2-C714-41A6-AF3B-43F6C030B927}")
	If (uCase(sStatus)="THE PACKAGE IS INSTALLED.") Then Uninstall("{65B612C2-C714-41A6-AF3B-43F6C030B927}")
	'return to mormal process
	MSI_GetPackageGUID (sMsiFile)
	MSI_GetPackageStatusByGuid(sProductCode)
	Log sStatus
	If (uCase(sStatus)="THE PACKAGE IS INSTALLED.") Then Uninstall(sProductCode)
	PreInstall=sStatus
End Function

Function UnInstall(sProductCode)
	Log "Msiexec /x " & sProductCode & " /L* " & """" & sMSIUninstallLog & """" & endPath
	ReturnVal = oShell.run ("Msiexec /x " & sProductCode & " /L* " & """" & sMSIUninstallLog & """" & endPath,0,True)
	Log "Return Code : " & ReturnVal
	If Not (ReturnVal = 0 Or ReturnVal = 3010) Then Fail("Could not Uninstall " & sPackageName & "!")
	If ofso.FileExists (sAllUsersDesktop & "\Epson MP Multi PC Projection.lnk") Then oFso.DeleteFile sAllUsersDesktop & "\Epson MP Multi PC Projection.lnk",true
	UnInstall=sStatus
End Function

Function Install()
	Log startPath & sMsiFile & """" & " /L* " & """" & sMSIInstallLog & """" & endPath
	ReturnVal = oShell.run (startPath & sMsiFile & """" & " /L* " & """" & sMSIInstallLog & """" & endPath,0,True)
	Log "Return Code : " & ReturnVal
	If Not (ReturnVal = 0 Or ReturnVal = 3010) Then 
		Fail("Could not Install " & sPackageName & "!")
	Else
		Log StrCurPath & "setacl.exe -on " & """" & sProgramFiles & "\Epson"& """" & " -ot file -actn ace -ace " & """" & "n:users;p:change" & """" & " -log " & """" &  sProgramFiles & "\Epson\setacl.txt" & """" & " -silent"
		oShell.run """" & StrCurPath & "setacl.exe" & """" & " -on " & """" & sProgramFiles & "\Epson"& """" & " -ot file -actn ace -ace " & """" & "n:users;p:change" & """" & " -log " & """" &  sProgramFiles & "\Epson\setacl.txt" & """" & " -silent"
		Log sAllUsersPrograms & "\EPSON Projector\EasyMP Multi PC Projection\EasyMP Multi PC Projection Ver.1.05.lnk" & " - " & sAllUsersDesktop & "\Epson MP Multi PC Projection.lnk"
		oFso.CopyFile sAllUsersPrograms & "\EPSON Projector\EasyMP Multi PC Projection\EasyMP Multi PC Projection Ver.1.05.lnk",sAllUsersDesktop & "\Epson MP Multi PC Projection.lnk",1
		Registry()
	End If
End Function

Private Function MSI_GetPackageStatusByGUID(sMsiGUID)
	Dim iStatus
	Dim sState
	On Error Resume Next
	iStatus=oMSI.ProductState(sMsiGUID)
    Select Case iStatus
		Case -6 : sState="Bad configuration."
		Case -2 : sState="Invalid argument."
		Case -1 : sState="The package is not installed."
		Case 1 : sState="The package is advertised, but not installed."
		Case 2 : sState="The package is absent."
		Case 5 : sState="The package is installed."
    End Select
	If (iStatus>-7) Then Log "MSI_GetPackageStatusByGUID : "& sState
	sStatus=sState
	MSI_GetPackageStatusByGUID=sState
End Function

Function MSI_GetPackageGUID(sMsiFile)
	Dim oSession
	Set oSession=oMsi.Opendatabase(StrCurPath & sMsiFile,0)
	If IsObject(oSession) Then
		Set View = oSession.OpenView("SELECT Value FROM Property where Property='ProductCode'") 'could include FileSize, etc
		View.Execute
		Do
			Set Record = View.Fetch
			If Record Is Nothing Then Exit Do
			sProductCode=Record.StringData(1)
		Loop
	End If
	Set View = Nothing
	If Len(sProductCode) Then Log "MSI_GetPackageStatus GUID: " & sProductCode
	MSI_GetPackageGUID=sStatus
End Function

Function Registry()
	ReturnVal = oShell.run ("reg add " & """" & "HKEY_LOCAL_MACHINE\SOFTWARE\MyCompany\Applications\" & sPackageName & """" & " /f /t REG_SZ /v InstallDate /d " & date(),0,True)
	ReturnVal = oShell.run ("reg add " & """" & "HKEY_LOCAL_MACHINE\SOFTWARE\MyCompany\Applications\" & sPackageName & """" & " /f /t REG_SZ /v Version /d " & sVersion,0,True)
	ReturnVal = oShell.run ("reg add " & """" & "HKEY_LOCAL_MACHINE\SOFTWARE\MyCompany\Applications\" & sPackageName & """" & " /f /t REG_SZ /v GUID /d " & sProductCode,0,True)
End Function
Posted by: esnelson16 10 years ago
White Belt
0

Has anyone successfully accomplished this yet? I am also getting the license agreement window.


Comments:
  • Nope. I'm using the msi file Epson provided to me. - orlith 10 years ago
  • I can share the msi file. But I'm quite sure it's only a FR version. - orlith 10 years ago
  • I was able to complete the install with no license agreement window. I used the AppDeploy package from ItNinja and it worked great. Now my only issue is that it will not allow the profile list or user setting to save. Giving me an error "Failed to save the file.(MA0000B) - esnelson16 10 years ago
  • seems to be an acl trouble no ? In my vbs script I set acl rights to r/w for all authenticated users on the folder C:\Program Files (x86)\EPSON. Maybe it can help in your case if not done already - orlith 10 years ago
  • Would you mind sharing your vbs script? I would like to see it. - esnelson16 10 years ago
  • Please see above. - orlith 10 years ago
  • Hello
    It seems that it is not getting license agreement file so copy file License.FR
    (As your doing french version ) from license folder present with source to same folder where setup.exe is present and then delete the license folder. then execute the iss file as follows
    e.g .
    setup.exe -s -f1c:\install.iss

    i tried many ways and finally the above solution worked for me. - nonearme 10 years ago
    • Will look at that option. Thanks for sharing this. - orlith 10 years ago
    • Thank you it worked - abhaypatil00@gmail.com 10 years ago
    • Thank you so much for this. I had also the issue with the License when using the french version. You saved me a lot of time ;) - jthys 10 years ago
    • Confirming that this works with EasyMP Network Projection 2.86. - L1ttl3J1m 9 years ago
    • mentioned solution works perfectly with v2.8 (German). - krulik 9 years ago
    • Worked fine with French v2.87 via script.
      I am deploying it with SCCM right now and and will report back. - Nawdiral 6 years ago
      • Confirm that is working with SCCM :
        setup.exe -s -f1 setup.iss
        Notice the name of the .ISS and the space ater -f1.

        Again, many thanks for your help. - Nawdiral 6 years ago
Rating comments in this legacy AppDeploy message board thread won't reorder them,
so that the conversation will remain readable.
 
This website uses cookies. By continuing to use this site and/or clicking the "Accept" button you are providing consent Quest Software and its affiliates do NOT sell the Personal Data you provide to us either when you register on our websites or when you do business with us. For more information about our Privacy Policy and our data protection efforts, please visit GDPR-HQ