Software Deployment

I just finished packaging this so you're in luck. A simple vbScript will do the trick.

'==========================================================================
' NAME: Install.vbs
' AUTHOR: robtk
' DATE  : 5/23/2012
' COMMENT: Installs Adobe Photoshop Elements 10 silently & without a serial #
' NOTE: Edit Setup.ini and change the following two properties
' DISABLEEMSFEATURES=1
' DISABLEOLSFEATURES=1
' This script must be in same folder as all the installation files.
'==========================================================================
On Error Resume Next
Dim oShell, path, rc, strValue, objFSO, command, aup, strFolder, strFilename
Const ForWriting = 2
Set oShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
strFilename = "Elements.ini"
aup = oShell.ExpandEnvironmentStrings("%ALLUSERSPROFILE%")

' Make the path of this script the current directory
path = Left(WScript.ScriptFullName, InstrRev(WScript.ScriptFullName, "\"))
oShell.CurrentDirectory = path

' Install Adobe Photoshop Elements 10
guid = "{EE549AF9-8FAA-4584-83B2-ECF1BC9DC1FF}"
strValue=oShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" & guid & "\UninstallString")
rc = InStr(strValue, guid)
If rc = 0 Then
 command = " start /wait setup.exe /UL1033 /V" & chr(34) & "ALLUSERS=1" & Chr(34)
 oShell.Run "cmd.exe /C" & command,,True
 Call createINI
End If

' This INI file will suppress a prompt to choose which country the user lives in on first launch.
Sub createINI
strFolder = aup & "\Application Data\Adobe\Elements Organizer\10.0"
Set f = objFSO.OpenTextFile(strFolder & "\" & strFilename, ForWriting, True)
f.WriteLine("[PSEInformation]")
f.WriteLine("Country=244")
f.WriteLine("LauncherLaunchCount=1")
f.Close
Set f = Nothing
End Sub

Set objFSO = Nothing
Set oShell = Nothing
WScript.Quit(0)

I think you need to look at amee (Adobe Application Manager Enterprise Edition)

http://www.adobe.com/devnet/creativesuite/enterprisedeployment.html