/build/static/layout/Breadcrumb_cap_w.png

Don't be a Stranger!

Sign up today to participate, stay informed, earn points and establish a reputation for yourself!

Sign up! or login
Views: 7.7k  |  Created: 10/22/2015 by: itsoftwaremgr

Average Rating: 0
Flash Player has 1 inventory records, 60 Questions, 8 Blogs and 31 links. Please help add to this by sharing more!

Deployment Tips (1)

Most Common Setup Type
Windows Installer (MSI)
Average Package Difficulty Rating
Rated 3 / 5 (Average) based on 1 ratings
Most Commonly Reported Deployment Method
Not Determined
0
Note
Our Organization was having very high failure rates for the deployment Adobe Flash, both the ActiveX and Plugin. The event viewer error entry details that it cant find the source of the previously installed versions of Flash player.
The script below will clean up the registry to enable the newer version to install. Run the vbs below then run the installers for adobe flash.
The code below will be relevant from previous flash versions (v 12) on-wards until when adobe changes the upgrade code.

-----cleanFlashReg.vbs-----
'Date 	: 14 Dec 2015
'The following code will remove Adobe Flash specific registries from that are not relevant to the currently installed version.
' "HKLM\SOFTWARE\Classes\Installer\Products\"
' "HKLM\SOFTWARE\Classes\Installer\Features\"
' "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\"
'Logic : Getlist of GUID based on upgradecode. For each upgrade code, check if its installed, if not installed remove from registry

strHklmSwClsInstProd= "SOFTWARE\Classes\Installer\Products\"
strHklmSwClsInstFeat= "SOFTWARE\Classes\Installer\Features\"
strHklmWowUninstall= "SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\" 'to find currently installed version

'the packed upgradecode for flash player activeX is 70836424B0797524CB59C543D816FDC1
strKeyPathActivX = "SOFTWARE\Classes\Installer\UpgradeCodes\70836424B0797524CB59C543D816FDC1"

'the packed upgradecode for flash player plugin is 95A1A58D25CD31D44954FEF373D9D45B
strKeyPathPlugIn = "SOFTWARE\Classes\Installer\UpgradeCodes\95A1A58D25CD31D44954FEF373D9D45B"


Const boolDbg=True 'True to turn on output
Const HKEY_LOCAL_MACHINE = &H80000002
Const REG_SZ = 1
Const REG_EXPAND_SZ = 2
Const REG_BINARY = 3
Const REG_DWORD = 4
Const REG_MULTI_SZ = 7


strComputer = "."
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")


cleanFlashRegistries(strKeyPathActivX)
cleanFlashRegistries(strKeyPathPlugIn)
set oReg = Nothing
WScript.Quit(0)

Function cleanFlashRegistries(strFlashUpgradeCode)
	write "Upgrade Code :" & strFlashUpgradeCode
	intResultEnumUpgradCode = -1
	intResultEnumProdCode = -1
	set arrValueNames = Nothing
	intResultEnumUpgradCode = oReg.EnumValues(HKEY_LOCAL_MACHINE, strFlashUpgradeCode, arrValueNames, arrValueTypes)

	if (intResultEnumUpgradCode=0) AND IsArrayDimmed(arrValueNames) then 'successfully executed oReg.EnumValues
		For i=0 To UBound(arrValueNames)
			write "Value Name: " & arrValueNames(i)
			write"GUID: " & strGUIDfromPackgedGUID(arrValueNames(i))
			'Logic to find currently installed version ->
			intResultEnumProdCode= oReg.EnumValues(HKEY_LOCAL_MACHINE, strHklmWowUninstall & strGUIDfromPackgedGUID(arrValueNames(i)), arrValueNamesUninstallAx, arrValueTypesUninstallAx)
			
			if intResultEnumProdCode= 0 then 'found
				write "found in uninstall" ' so its currently installed
			Else
				'nuke the codes from the registry
				'Logic to delete the not currently installed verison ->
				write "Deleting the following"
				write strHklmSwClsInstProd & arrValueNames(i)
				DeleteSubkeys HKEY_LOCAL_MACHINE, strHklmSwClsInstProd & arrValueNames(i)
				write strHklmSwClsInstFeat & arrValueNames(i)
				DeleteSubkeys HKEY_LOCAL_MACHINE, strHklmSwClsInstProd & arrValueNames(i)
				write strFlashUpgradeCode & ":" & arrValueNames(i)
				oReg.DeleteValue HKEY_LOCAL_MACHINE,strFlashUpgradeCode,arrValueNames(i)
			End if
			write " "
		Next
	Else
		write "no entires found"
	End If
End Function

'input : [string] Packed Guid
'output: [string] GUID with Curley Brace {xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx}
Function strGUIDfromPackgedGUID(strPackedGUID)
	dim str18,str24,str34,str42,str52,str62,str72,str82,str92,str102,str112
	str18=StrReverse(MID(strPackedGUID,1,8))
	str24=StrReverse(MID(strPackedGUID,9,4))
	str34=StrReverse(MID(strPackedGUID,13,4))
	str42=StrReverse(MID(strPackedGUID,17,2))
	str52=StrReverse(MID(strPackedGUID,19,2))
	str62=StrReverse(MID(strPackedGUID,21,2))
	str72=StrReverse(MID(strPackedGUID,23,2))
	str82=StrReverse(MID(strPackedGUID,25,2))
	str92=StrReverse(MID(strPackedGUID,27,2))
	str102=StrReverse(MID(strPackedGUID,29,2))
	str112=StrReverse(MID(strPackedGUID,31,2))
	strGUIDfromPackgedGUID="{" & str18 & "-" & str24 & "-" & str34 & "-" & str42 & str52 & "-" & str62 & str72 & str82 & str92 & str102 & str112 & "}"
End Function

'script from the scripting guys site @ microsoft devleoper.
Sub DeleteSubkeys(HKEY_LOCAL_MACHINE, strKeyPath) 
    oReg.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubkeys 

    If IsArray(arrSubkeys) Then 
        For Each strSubkey In arrSubkeys 
            DeleteSubkeys HKEY_LOCAL_MACHINE, strKeyPath & "\" & strSubkey 
        Next 
    End If 
    oReg.DeleteKey HKEY_LOCAL_MACHINE, strKeyPath 
End Sub

Function write(strIn)
	If boolDbg Then
		Wscript.echo strIn
	end if
End Function

'Below code from http://wiki.mcneel.com/developer/scriptsamples/emptyarray
Function IsArrayDimmed(arr)
   IsArrayDimmed = False
   If IsArray(arr) Then
     On Error Resume Next
     Dim ub : ub = UBound(arr)
     If (Err.Number = 0) And (ub >= 0) Then IsArrayDimmed = True
   End If  
 End Function
Setup Information:
Setup Type: Windows Installer (MSI)
Deployment Method Used: unspecified
Deployment Difficulty: Average
Platform(s): Windows
  • Hi, this works for me. Thank you... - stevecharon 8 years ago
  • you are welcome.. glad to be of help - tsanjev 8 years ago

Inventory Records (1)

View inventory records anonymously contributed by opt-in users of the K1000 Systems Management Appliance.

Versions

Flash Player

Version

19

Questions & Answers (60)

Questions & Answers related to Adobe Flash Player

1
ANSWERS
2
ANSWERS
2
ANSWERS
1
ANSWERED
1
ANSWERS
9
ANSWERS
2
ANSWERS
1
ANSWERS
1
ANSWERS
5
ANSWERED
1
ANSWERS
2
ANSWERED
4
ANSWERED
2
ANSWERS
1
ANSWERS
3
ANSWERS

Reviews (0)

Reviews related to Adobe Flash Player

 
This website uses cookies. By continuing to use this site and/or clicking the "Accept" button you are providing consent Quest Software and its affiliates do NOT sell the Personal Data you provide to us either when you register on our websites or when you do business with us. For more information about our Privacy Policy and our data protection efforts, please visit GDPR-HQ