1. Download installer

https://www.epicgames.com/fortnite/en-US/success

2. Deploy software with a batch script

Obtain fsync.exe - http://www.vicosoft.it/en/fsync.html

NB - This script was initially created in Silent Batch Maker, a very useful tool to help create silent installers quickly - https://github.com/nsy16/SilentBatchMaker/releases

install.cmd

@echo off&cls
for %%a in ("%~dp0\.") do set _parentdir=%%~nxa
title %_parentdir%

:: Install Fortnite

set _fPath=%~dp0EpicInstaller-9.7.0-fortnite-ddded0cb6bc64da581be8cc4bdd16da3.msi
set _swtch=/passive
set _regKy={A398FCC0-8E8B-409E-90E9-ACF4671633F2}
set _regDN=Epic Games Launcher
set _regDV=1.1.183.0

:: query registry for DisplayVersion 64bit and 32bit uninstall locations
for /f "tokens=3" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%_regKy%" /v "DisplayVersion" 2^>nul') do if "%%a" geq "%_regDV%" goto :end
for /f "tokens=3" %%a in ('reg query "HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\%_regKy%" /v "DisplayVersion" 2^>nul') do if "%%a" geq "%_regDV%" goto :end

:: install software
echo Installing %_regDN% %_regDV%
start /wait "" "%_fPath%" %_swtch%

:: overwrite folder with 'good' version
echo Updating cache files 350+...
set _src=%~dp0Fortnite
set _dst=C:\Program Files\Epic Games\Fortnite
if not exist "%temp%\fsync.exe" copy "%~dp0fsync.exe" "%temp%" >nul 
md "%_dst%" 2>nul
"%temp%\fsync.exe" "%_src%" "%_dst%" /k /f

:end

:: cleanup
del "%userprofile%\Desktop\Fortnite.url" 2>nul

3. Update local cache

Launch game and ensure it is updated

Use the following script to update your local installer cache

@echo off&cls
for %%a in ("%~dp0\.") do set _parentdir=%%~nxa
title %_parentdir%

:: Update Cache Fortnite

:: overwrite folder with 'good' version
echo Updating cache files 350+...
set _src=C:\Program Files\Epic Games\Fortnite
set _dst=%~dp0Fortnite
if not exist "%temp%\fsync.exe" copy "%~dp0fsync.exe" "%temp%" >nul 
"%temp%\fsync.exe" "%_src%" "%_dst%" /k /f

:end
pause